|
| 1 | +/** Provides predicates for recognizing clickjacking-related response-header configuration. */ |
| 2 | + |
| 3 | +import csharp |
| 4 | +import semmle.code.csharp.dataflow.DataFlow |
| 5 | +import semmle.code.csharp.frameworks.microsoft.AspNetCore |
| 6 | +import semmle.code.csharp.frameworks.system.Web |
| 7 | + |
| 8 | +/** Holds if `name` is the `X-Frame-Options` header name, ignoring case. */ |
| 9 | +bindingset[name] |
| 10 | +predicate isXFrameOptionsText(string name) { name.toLowerCase() = "x-frame-options" } |
| 11 | + |
| 12 | +/** Holds if `name` is the enforced `Content-Security-Policy` header name, ignoring case. */ |
| 13 | +bindingset[name] |
| 14 | +predicate isContentSecurityPolicyText(string name) { |
| 15 | + name.toLowerCase() = "content-security-policy" |
| 16 | +} |
| 17 | + |
| 18 | +/** |
| 19 | + * Holds if `value` contains a `frame-ancestors` directive at the start of a CSP policy or |
| 20 | + * after a directive or policy separator. |
| 21 | + */ |
| 22 | +bindingset[value] |
| 23 | +predicate containsFrameAncestorsDirective(string value) { |
| 24 | + value.regexpMatch("(?is)(^|.*[;,])\\s*frame-ancestors(\\s|;|$).*") |
| 25 | +} |
| 26 | + |
| 27 | +private predicate isXFrameOptionsHeaderNameExpr(Expr name) { |
| 28 | + isXFrameOptionsText(name.stripImplicit().getValue()) |
| 29 | + or |
| 30 | + name.stripImplicit().(FieldAccess).getTarget() = |
| 31 | + any(MicrosoftNetHttpHeadersHeaderNames f).getXFrameOptionsField() |
| 32 | +} |
| 33 | + |
| 34 | +private predicate isContentSecurityPolicyHeaderNameExpr(Expr name) { |
| 35 | + isContentSecurityPolicyText(name.stripImplicit().getValue()) or |
| 36 | + name.stripImplicit().(FieldAccess).getTarget() = |
| 37 | + any(MicrosoftNetHttpHeadersHeaderNames f).getContentSecurityPolicyField() |
| 38 | +} |
| 39 | + |
| 40 | +private predicate containsFrameAncestorsDirectiveExpr(Expr value) { |
| 41 | + containsFrameAncestorsDirective(value.stripImplicit().getValue()) |
| 42 | +} |
| 43 | + |
| 44 | +private predicate isDirectResponseHeadersAccess(Expr expr) { |
| 45 | + exists(PropertyAccess headers, MicrosoftAspNetCoreHttpHttpResponse response | |
| 46 | + expr.stripImplicit() = headers and headers.getProperty() = response.getHeadersProperty() |
| 47 | + ) |
| 48 | +} |
| 49 | + |
| 50 | +private predicate isCallOnResponseHeadersAccess(Call call) { |
| 51 | + exists(Expr qualifier | |
| 52 | + call.(MethodCall).getQualifier() = qualifier or |
| 53 | + call.(ExtensionMethodCall).getArgument(0) = qualifier or |
| 54 | + call.(AccessorCall).getQualifier() = qualifier |
| 55 | + | |
| 56 | + exists(Expr directAccess | |
| 57 | + isDirectResponseHeadersAccess(directAccess) and |
| 58 | + DataFlow::localExprFlow(directAccess, qualifier.stripImplicit()) |
| 59 | + ) |
| 60 | + ) |
| 61 | +} |
| 62 | + |
| 63 | +private predicate isClickjackingHeaderCall(MethodCall call) { |
| 64 | + ( |
| 65 | + call.getTarget() = any(SystemWebHttpResponseClass r).getAppendHeaderMethod() or |
| 66 | + call.getTarget() = any(SystemWebHttpResponseClass r).getAddHeaderMethod() |
| 67 | + ) and |
| 68 | + ( |
| 69 | + isXFrameOptionsHeaderNameExpr(call.getArgumentForName("name")) |
| 70 | + or |
| 71 | + isContentSecurityPolicyHeaderNameExpr(call.getArgumentForName("name")) and |
| 72 | + containsFrameAncestorsDirectiveExpr(call.getArgumentForName("value")) |
| 73 | + ) |
| 74 | +} |
| 75 | + |
| 76 | +private predicate isClickjackingHeaderDictionaryLikeWrite(Call call) { |
| 77 | + ( |
| 78 | + call.getTarget().hasUndecoratedName(["Append", "Add", "TryAdd"]) |
| 79 | + or |
| 80 | + call.(IndexerCall).getTarget() instanceof Setter |
| 81 | + ) and |
| 82 | + ( |
| 83 | + isXFrameOptionsHeaderNameExpr(call.getArgumentForName("key")) |
| 84 | + or |
| 85 | + isContentSecurityPolicyHeaderNameExpr(call.getArgumentForName("key")) and |
| 86 | + containsFrameAncestorsDirectiveExpr(call.getArgumentForName("value")) |
| 87 | + ) |
| 88 | +} |
| 89 | + |
| 90 | +private predicate isClickjackingPropertyWrite(Call c) { |
| 91 | + c.getTarget() instanceof Setter and |
| 92 | + ( |
| 93 | + c.(PropertyCall).getProperty() = |
| 94 | + any(MicrosoftAspNetCoreHttpIHeaderDictionary dic).getXFrameOptionsProperty() |
| 95 | + or |
| 96 | + c.(PropertyCall).getProperty() = |
| 97 | + any(MicrosoftAspNetCoreHttpIHeaderDictionary dic).getContentSecurityPolicyProperty() and |
| 98 | + containsFrameAncestorsDirectiveExpr(c.getArgumentForName("value")) |
| 99 | + ) |
| 100 | +} |
| 101 | + |
| 102 | +/** Gets an expression that configures a clickjacking-related response header. */ |
| 103 | +Call getAClickjackingHeaderWrite() { |
| 104 | + isClickjackingHeaderCall(result) |
| 105 | + or |
| 106 | + isCallOnResponseHeadersAccess(result) and |
| 107 | + ( |
| 108 | + isClickjackingHeaderDictionaryLikeWrite(result) |
| 109 | + or |
| 110 | + isClickjackingPropertyWrite(result) |
| 111 | + ) |
| 112 | +} |
0 commit comments